[WD20 et +] Vérifier un numéro de TVA via WebService (EU)

Au préalable, vous devez installer le Webservice dans votre projet : ec.europa.eu/taxation_customs/vies/checkVatService.wsdl

Code (Text):

PROCEDURE CheckVAT(LOCAL pVATNumber est chaîne,LOCAL bFullErrors est booléen)

LOCAL
    e_bResult est booléen = Faux
    e_bValid est booléen = Faux
    e_sErrorMessage est chaîne=""
    ////////////////////////////
    e_sCountryCode est chaîne = Gauche(pVATNumber,2)
    e_sVATNumber est chaîne = Milieu(pVATNumber,3)
    // Retourné par le WEB Service
    e_sAddress est chaîne = ""
    e_sName est chaîne = ""
    e_sValid est chaîne = ""
    ////////////////////////////

// Si la longueur est moindre que 9, ce n'est pas un bon numéro de tva
SI Taille(pVATNumber)<=9 ALORS
    e_bResult=Vrai
    e_bValid=Faux
    e_sErrorMessage="Mauvais numéro de TVA"
    RENVOYER(e_bResult,e_bValid,"","",e_sErrorMessage)  
FIN

e_CVS             est un checkVatService.checkVat
e_CVS_Request     est checkVatService.checkVatResponse
e_CVS.countryCode = e_sCountryCode
e_CVS.vatNumber = e_sVATNumber
e_CVS_Request = checkVatService.CheckVAT(e_CVS)

// Valeurs retournées /////
e_sValid = e_CVS_Request.valid
e_sName = e_CVS_Request.name
e_sAddress = e_CVS_Request.address
//////////////////
SI e_sValid = "1" ALORS
    // "1" VIES Webservice a trouvé le code TVA correct
    e_bResult = Vrai
    e_bValid = Vrai
    e_sErrorMessage = ""
SINON
    e_bResult = Vrai
    e_bValid = Faux
    e_sName = ""
    e_sAddress = ""  
    e_sErrorMessage = "Pas trouvé le numéro de TVA"
FIN
RENVOYER(e_bResult,e_bValid,e_sName,e_sAddress,e_sErrorMessage)

CAS ERREUR:
e_bResult=Faux
e_bValid=Faux
e_sName=""
e_sAddress=""  
SI bFullErrors=Vrai ALORS
    e_sErrorMessage = ErreurInfo(errComplet)  
SINON
    e_sErrorMessage = "Problème avec le Web Service de VIES"
FIN  

RENVOYER(e_bResult,e_bValid,e_sName,e_sAddress,e_sErrorMessage)  

CAS EXCEPTION:
e_bResult = Faux
e_bValid = Faux
e_sName = ""
e_sAddress = ""  
SI bFullErrors = Vrai ALORS
    e_sErrorMessage=ExceptionInfo(errComplet)  
SINON
    e_sErrorMessage = "Problème avec le Web Service de VIES"
FIN      
RENVOYER(e_bResult,e_bValid,e_sName,e_sAddress,e_sErrorMessage)