AIDE IMPORTATION D UNE BASE EXCEL DANS UN HYPERFILE windev

Bonjour à tous et toutes,

Un bail que j'avais pas posté ici.

J'ai justement créé une procédure hier soir à ce sujet d'import de fichier excel car je n'arrive pas à utiliser la fonction HimporteXLS. ( <- si quelqu'un exemple concret là dessus)
la fonction utilise des indirections. Vous donner le chemin du fichier Excel et ça crée un .fic avec toutes les données dedans.
Le seul point qui manque à cette fonction est l'ajout du fichier .fic dans l'analyse en automatique. Si quelqu'un sait faire je suis preneur. (Pas russi avec HDéclare)

[windev]

PROCÉDURE ImportExcel(sCheminfichier est une chaîne)

sNomColonne est une chaîne = ""
sNomFichier est une chaîne = fExtraitChemin(sCheminfichier, fFichier)

//On supprime le .fic s'il existe deja
SI PAS fSupprime(fExtraitChemin(sCheminfichier,fRépertoire) + sNomFichier + ".fic",frLectureSeule) ALORS ErreurInfo(errComplet)

TabExcel est un xlsDocument = xlsOuvre(sCheminfichier,xlsEcriture)
SI ErreurDétectée = Faux ALORS
nBLigne est un entier = xlsNbLigne(TabExcel)
nBColonne est un entier = xlsNbColonne(TabExcel)
POUR i = 1 À nBColonne
sNomColonne += xlsDonnée(TabExcel,1,i) + ","
FIN
//on enleve la derniere virgule
sNomColonne = Gauche(sNomColonne,Taille(sNomColonne)-1)

//Création du fichier
UnFichier est une Description de Fichier
UneRubrique est une Description de Rubrique
//sdLEFICHIER est une source de données = sNomFichier

// Description du fichier de données
UnFichier..Nom = sNomFichier
UnFichier..Type = hFichierNormal
//UnFichier..CryptageFic = hCryptageStandard

POUR TOUTE CHAÎNE sChaine DE sNomColonne SEPAREE PAR ","
UneRubrique..Nom = sChaine
UneRubrique..Type = hRubTexte
UneRubrique..Taille = 256
HDécritRubrique(UnFichier, UneRubrique)
FIN

// Valide la description du fichier de données
HDécritFichier(UnFichier)

// Création du fichier de données Client (reconnu car déclaré comme source de données)
HCréation(sNomFichier)



POUR i = 2 À nBLigne
HRAZ({sNomFichier,indFichier})
j est un entier = 0
POUR TOUTE CHAÎNE sChaine DE sNomColonne SEPAREE PAR ","
j += 1
//Trace(sNomFichier + "." + schaine)
{sNomFichier + "." + schaine,indRubrique} = xlsDonnée(TabExcel,i,j)
FIN
SI PAS HAjoute({sNomFichier,indFichier}) ALORS ErreurInfo(errComplet)
FIN


SINON
Erreur("Attention ! le fichier " + sCheminfichier + " est déjà ouvert sur un poste de travail !")
FinProgramme()
FIN
xlsFerme(TabExcel)

HDéclareExterne(fExtraitChemin(sCheminfichier,fRépertoire) + sNomFichier + ".fic",sNomFichier)

[/windev]

 

Bonjour visiteur, Merci de vous Inscrire ou de vous connectez pour voir les liens!

Bonjour,
Quelqu’un aurais une solution pour importer une base excel avec toute sa structure dans HyperFile windev
// Déclaration des variables
ResDonnée est une chaîne
FichierXLS est une chaîne
IdFichierXLS est un entier

// Sélection du fichier XLS
FichierXLS = fSélecteur("", "", "Sélection d'un fichier XLS", ...
"Fichier XLS" + TAB + "*.XLS", "XLS", fselOuvre+fselExiste)
// Ouverture du fichier sélectionné
IdFichierXLS = xlsOuvre(FichierXLS)
SI IdFichierXLS <> -1 ALORS
// Récupération du contenu d'une cellule
ResDonnée = xlsDonnée(IdFichierXLS, 3, 4, Faux)
SI ResDonnée <> xlsDonnéeErreur ALORS
SI ResDonnée = "" ALORS
// La cellule est vide
Info("La cellule est vide")
SINON
// Affichage du contenu de la cellule
Info("Le contenu de la cellule est : " + ResDonnée)
FIN
SINON
// Affichage du message d'erreur si la récupération n'a pas été effectuée
Erreur(xlsMsgErreur(IdFichierXLS))
FIN
SINON
// Affichage du message d'erreur si l'ouverture n'a pas été effectuée
Erreur(xlsMsgErreur(IdFichierXLS))
FIN

Cliquez pour agrandir...